module modexpng_sdp_36k_x32_x16_wrapper_generic
(
    clk, clk_bus,
    
    ena, wea,
    addra, dina,
    
    enb,
    addrb, doutb
);


    //
    // Headers
    //
    `include "modexpng_parameters.vh"


    //
    // Ports
    //
    input                                     clk;
    input                                     clk_bus;
    
    input                                     ena;
    input                                     wea;
    input  [BANK_ADDR_W + OP_ADDR_W     -1:0] addra;
    input  [              WORD_W        -1:0] dina;
    
    input                                     enb;
    input  [BANK_ADDR_W + BUS_OP_ADDR_W -1:0] addrb;
    output [              BUS_DATA_W    -1:0] doutb;

    
    //
    // Memory
    //
    reg [BUS_DATA_W -1:0] mem[0:2**(BANK_ADDR_W+BUS_OP_ADDR_W)-1];
   
    //
    // Write Port
    //
    wire [BANK_ADDR_W + BUS_OP_ADDR_W -2:0] addra_msb = addra[BANK_ADDR_W + BUS_OP_ADDR_W -1:1];
    wire                                    addra_lsb = addra[0];
    
    always @(posedge clk)
        //
        if (ena && wea) begin
           if (addra_lsb) mem[addra_msb][BUS_DATA_W-1:WORD_W] <= dina;
           else           mem[addra_msb][    WORD_W-1:     0] <= dina;
        end
            
    //
    // Read Port
    //
    reg [BUS_DATA_W -1:0] doutb_reg;
    
    assign doutb = doutb_reg;
        
    always @(posedge clk_bus)
        //
        if (enb)
            doutb_reg <= mem[addrb];
            
    
endmodule